It's Not A Bug, It's A Feature Just another Developer weblog

<%

Class SmarterTrack_svcTicket
'#####################################################################################################

'#################################################################
'VERY IMPORTANT: When attempting to get this class to work we were getting the following error: '#################################################################
    'WSDLReader error '80020009'
    'WSDLReader:Loading of the WSDL file failed HRESULT=0x80040154: Class not registered -
    'Client:An unanticipated error occurred during the processing of this request. HRESULT=0x80040154: Class not registered
   
    'The error occurred the following line in "Class_Initialize":
    'oSOAP.mssoapinit WebserviceURL & "svcTickets.asmx?WSDL", "svcTickets"
   
    'To get this SOAP functionality to work, make sure that the following is installed on the machine (this fixed our error above):
    '1) SOAP Toolkit 3.0 (http://www.microsoft.com/downloads/en/details.aspx?FamilyId=C943C0DD-CEEC-4088-9753-86F052EC8450&displaylang=en)
    '2) MSXML 4.0 Service Pack 2 (Microsoft XML Core Services)
    '   - http://www.microsoft.com/downloads/en/details.aspx?familyid=3144b72b-b4f2-46da-b4b6-c5d7485f2b42&displaylang=en
    '   - install msxml.msi

    'Private Declarations
    Private oSOAP
    Private svcTicketsWDSL
    Private svcTicketsNamespace
    Private svcResponse
    'Public Declarations
    Public AgentUserName
    Public AgentPassword
    Public WebserviceURL
    Public WebServiceTimeout
    Public TicketNumber
    Public Result
    Public ResultCode
    Public RequestResult
    'Create & Destroy Methods
    Private Sub Class_Initialize
        WebserviceURL = "http://localhost:9996/services/" 'Default Value (DEV Address)
        AgentUserName = "admin"
        AgentPassword = "admin"
        WebServiceTimeout = 10000 '10 seconds
        Set oSOAP = Server.CreateObject("MSSOAP.SoapClient30")
        oSOAP.ClientProperty("ServerHTTPRequest") = True
        oSOAP.mssoapinit WebserviceURL & "svcTickets.asmx?WSDL", "svcTickets"
        oSoap.ConnectorProperty("Timeout") = WebServiceTimeout
    End Sub

    Private Sub Class_Terminate
        Set oSOAP = Nothing
    End Sub
    'Subroutines
    Public Function CreateTicket(byVal intDeptID,byVal UserEmailAddress, byVal Subject, byVal MessageBody, byVal SendAutoRespond)
        Response.Write "<hr>CreateTicket()<br>"
        Set svcResponse = oSOAP.CreateTicket(AgentUserName, AgentPassword, intDeptID, UserEmailAddress, Subject, MessageBody , false, SendAutoRespond)
        Call ProcessResponse()
        TicketNumber = RequestResult
    End Function
   
    Public Function GetTicketURL()
        'Response.Write "<hr>AddTicketNote('" & TicketNumber & "')<br>" 'For Debugging
        Set svcResponse = oSOAP.GetTicketURL(AgentUserName, AgentPassword, TicketNumber)
        Call ProcessResponse()
        GetTicketURl = RequestResult
    End Function

    Public Function ProcessResponse()
        For Each Node In svcResponse
            'Response.Write Node.tagName & " : " & Node.xml & "<br>"
            Select Case Node.tagName
                Case "RequestResult" 'Ticket Number
                    RequestResult = Node.Text
                Case "Message"
                    Message = Node.Text
                Case "Result"
                    Result = Node.Text
                Case "ResultCode"
                    ResultCode = Node.Text
                Case Else
                    'Response.write "CreateTicket : Unknown Response Node = " & Node.tagName & "<br>"
            End Select
        Next
    End Function
'#####################################################################################################
End Class
'Sample Usuage
Dim Ticket
Set Ticket = New SmarterTrack_svcTicket
Ticket.CreateTicket 1,"customer@summit-pro.com", "Missing Items On Order", "Customer reported they did not receive there widget", True
Response.Write ( Ticket.GetTicketURL() )
Set Ticket = Nothing
%>